diff --git a/packages/pob-dev-version/default.nix b/packages/pob-dev-version/default.nix
new file mode 100644
index 0000000..759c55e
--- /dev/null
+++ b/packages/pob-dev-version/default.nix
@@ -0,0 +1,89 @@
+{
+  pkgs,
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  unzip,
+  ...
+}:
+let
+  data = stdenv.mkDerivation (finalAttrs: {
+    pname = "path-of-building-data";
+    version = "dev-version";
+
+    src = fetchFromGitHub {
+      owner = "PathOfBuildingCommunity";
+      repo = "PathOfBuilding";
+      rev = "80dfb6f56bb41cad19f9904b3baacc15b8ecf0f7";
+      hash = "sha256-apZYU0PrB3wehzJPNNH3aFKLMA/fK5vo+dtgbho6EiM=";
+    };
+
+    nativeBuildInputs = [ unzip ];
+
+    buildCommand = ''
+      # I have absolutely no idea how this file is generated
+      # and I don't think I want to know. The Flatpak also does this.
+      unzip -j -d $out $src/runtime-win32.zip lua/sha1.lua
+
+      # Install the actual data
+      cp -r $src/src $src/runtime/lua/*.lua $src/manifest.xml $out
+
+      # Pretend this is an official build so we don't get the ugly "dev mode" warning
+      substituteInPlace $out/manifest.xml --replace '<Version' '<Version platform="nixos"'
+      touch $out/installed.cfg
+
+      # Completely stub out the update check
+      chmod +w $out/src/UpdateCheck.lua
+      echo 'return "none"' > $out/src/UpdateCheck.lua
+    '';
+  });
+in
+stdenv.mkDerivation {
+  pname = "path-of-building";
+  version = "${data.version}-unstable-2023-04-09";
+
+  src = fetchFromGitHub {
+    owner = "ernstp";
+    repo = "pobfrontend";
+    rev = "9faa19aa362f975737169824c1578d5011487c18";
+    hash = "sha256-zhw2PZ6ZNMgZ2hG+a6AcYBkeg7kbBHNc2eSt4if17Wk=";
+  };
+
+  nativeBuildInputs = with pkgs; [
+    meson
+    ninja
+    pkg-config
+    kdePackages.qttools
+    kdePackages.wrapQtAppsHook
+  ];
+  buildInputs = with pkgs; [
+    kdePackages.qtbase
+    luajit
+    luajit.pkgs.lua-curl
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm555 pobfrontend $out/bin/pobfrontend
+    runHook postInstall
+  '';
+
+  preFixup = ''
+    qtWrapperArgs+=(
+      --set LUA_PATH "$LUA_PATH"
+      --set LUA_CPATH "$LUA_CPATH"
+      --chdir "${data}"
+    )
+  '';
+
+  passthru.data = data;
+
+  meta = {
+    description = "Offline build planner for Path of Exile";
+    homepage = "https://pathofbuilding.community/";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.k900 ];
+    mainProgram = "pobfrontend";
+    broken = stdenv.isDarwin; # doesn't find uic6 for some reason
+  };
+}